Scripting 언어 및 Visual Basic 을 이용한 IIS 관리 자동화 구현
3.-2 간단한 ADSI(Active Directory Service Interface) 예제
by SongGun
안녕하세요? 송원석입니다. 오랜만에 인사드립니다. ^_^;... 몇일간 휴가도 다녀오고, 새 직장도 알아보고 했더니 한 일도 없이 날짜만 훌쩍 지나버렸습니다. 얼렁뚱땅하는 사이에 지난번 강좌와 한 보름 정도의 텀이 생겨버렸군요. 휴가도 다녀왔으니 다시 기운내서 열심히 강좌를 쓰도록 하겠습니다.
이 강좌의 초안을 작성하고 있던 시점인 2000 년 8 월 2 일 현재, 드디어 ADSI 와 메타베이스 관련 참고 서적이 출판될 것이라는 것을 알게 되었습니다. Wrox 의 빨간색 표지의 시리즈들 중 하나로, 정보문화사에서 출판되는 'Professional ADSI Programming'이라는 책입니다. 2000 년 8 월 7 일 출판 예정이라고하니, 여러분들께서 이 강좌를 보실 무렵에는 이미 서점에 나와있겠군요. 이 책에 대해 더 자세한 정보를 알고 싶으신 분은 와우북을 참고하시기 바랍니다. (물론, 저는 정보문화사나 와우북과 아무런 관계도 없습니다. -_-+...)
◈ ADSI 예제 프로그램 - 02.
지난번 강좌에서 ADSI 를 사용한 예제를 하나 살펴보았습니다만, 아무 설명도 없이 예제부터 보여드려서 ADSI 를 제대로 이해하기에는 힘드셨을 것입니다. 그럼에도 불구하고, 이번 강좌에서도 역시 설명없이 몇 가지 예제를 보여드리도록 하겠습니다. 제 나름대로 약간 고민을 해봤습니다만, 지루한 설명을 장황하게 늘어놓는 것보다는 코드를 직접 보여드리고, 그 코드에 관해 설명드리는 것이 대부분 ASP 프로그래머인 여러분들에게 더욱 쉽게 다가갈 것이라고 생각했기 때문입니다.
다음은 두번째 ADSI 예제 프로그램(소스 다운로드)입니다. 이 ASP 프로그램은 실행되는 컴퓨터에 설치된 Binding 가능한 모든 ADSI 제공자의 목록을 리스트로 보여줍니다.
<%
'******************************************************************
'*
'* # TITLE : ADSI Test Program - 02.
'* # PROGRAM NAME : ADSI02.asp
'* # PROGRAM CONT. : 현재 로컬 머신에서 사용 가능한
'* 모든 ADSI 제공자의 목록을 보여준다.
'* # SUB ROUTINE :
'* # CLIENT SCRIPT :
'* # INCLUDE FILES :
'* # MODIFICATIONS :
'* 1. 2000/08/11 송원석 프로그램 처음 작성
'*
'******************************************************************
Option Explicit
On Error Resume Next
Response.Buffer = True
'******************************************************************
'*
'* 변수 선언
'*
'******************************************************************
Dim ADs
Dim Provider
Dim i
'******************************************************************
'*
'* ADSI 제공자들의 목록을 가져온다.
'*
'******************************************************************
Set ADs = GetObject("ADs:")
%>
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//EN">
<html>
<head>
<title>ADSI 테스트 02</title>
</head>
<body>
<font size="2">
◈ 사용 가능한 ADSI 제공자 목록<br>
<table border="0" cellpadding="2" cellspacing="1" bgcolor="#BBBCE6">
<tr bgcolor="#DBDCF6">
<td nowrap align="center"><font size="2"> 순번 </font></td>
<td nowrap align="center"><font size="2"> ADSI 제공자 </font></td>
</tr>
<%
i = 1
For Each Provider In ADs
%>
<tr bgcolor="White">
<td nowrap align="center"><font size="2"> <%= Right("00" & i, 3) %> </font></td>
<td nowrap><font size="2"> <%= Provider.Name %> </font></td>
</tr>
<%
i = i + 1
Next
%>
</table><br><br>
<% Response.Flush %>
<% Set ADs = Nothing %>
</font>
</body>
</html> |
 |
이 그림에서 보이는 것처럼 목록의 마지막 ADSI 제공자는 IIS: 입니다. 이제 ADSI 를 이용해서 IIS 를 제어한다는 것의 의미를 서서히 느끼실 수 있으실 것입니다. 현재 진행되는 ADSI 강좌 자체는 ADSI 에 대한 이해의 폭을 넓히기 위해서 IIS: ADSI 제공자가 아니라 WinNT: ADSI 제공자를 예를 들어 설명하고 있지만, 사실 저희는 조금씩 그리고 정확하게 주제에 접근해가고 있는 것입니다.
◈ ADSI 예제 프로그램 - 03.
다음은 세번째 ADSI 예제 프로그램(소스 다운로드)입니다. 이 ASP 프로그램은 'UserID' 상수에 지정한 사용자의 계정 정보를 보여줍니다.
<%
'******************************************************************
'*
'* # TITLE : ADSI Test Program - 03.
'* # PROGRAM NAME : ADSI03.asp
'* # PROGRAM CONT. : 사용자 계정 정보를 보여준다.
'* # SUB ROUTINE :
'* # CLIENT SCRIPT :
'* # INCLUDE FILES :
'* # MODIFICATIONS :
'* 1. 2000/08/12 송원석 프로그램 처음 작성
'*
'******************************************************************
Option Explicit
On Error Resume Next
Response.Buffer = True
'******************************************************************
'*
'* 컴퓨터 이름 상수, 테스트 사용자 계정 상수
'*
'* 반드시 MachineName 상수를 자신의 컴퓨터 이름으로 바꿔주어야
'* 프로그램이 정상적으로 작동한다.
'*
'* 반드시 UserID 상수를 자신의 컴퓨터에 존재하는 테스트 사용자 계정으로
'* 바꿔주어야 프로그램이 정상적으로 작동한다.
'*
'******************************************************************
Const MachineName = "송원석"
Const UserID = "ADSI_User"
Const ADS_UF_PASSWD_CANT_CHANGE = &h0040
Const ADS_UF_DONT_EXPIRE_PASSWD = &h10000
'******************************************************************
'*
'* 변수 선언
'*
'******************************************************************
Dim User
Dim TempStr
'******************************************************************
'*
'* ADSI 를 이용해 지정 컴퓨터의 지정 사용자 정보를 가져온다.
'*
'******************************************************************
Set User = GetObject("WinNT://" & MachineName & "/" & UserID & ",User")
%>
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//EN">
<html>
<head>
<title>ADSI 테스트 03</title>
</head>
<body>
<font size="2">
◈ '<%= UserID %>' 계정 정보<br>
<table border="0" cellpadding="2" cellspacing="1" bgcolor="#BBBCE6">
<tr bgcolor="#DBDCF6">
<td nowrap align="right"><font size="2"> 계 정 </font></td>
<td nowrap bgcolor="White"><font size="2"> <%= User.Name %> </font></td>
</tr>
<tr bgcolor="#DBDCF6">
<td nowrap align="right"><font size="2"> 긴 이름 </font></td>
<td nowrap bgcolor="White"><font size="2"> <%= User.FullName %> </font></td>
</tr>
<tr bgcolor="#DBDCF6">
<td nowrap align="right"><font size="2"> 설 명 </font></td>
<td nowrap bgcolor="White"><font size="2"> <%= User.Description %> </font></td>
</tr>
<tr bgcolor="#DBDCF6">
<td nowrap align="right"><font size="2"> 다음 로그온할 때 반드시 암호 변경 </font></td>
<%
If User.PasswordExpired = 1 Then
TempStr = "On"
Else
TempStr = "Off"
End If
%>
<td nowrap bgcolor="White"><font size="2"> <%= TempStr %> </font></td>
</tr>
<tr bgcolor="#DBDCF6">
<td nowrap align="right"><font size="2"> 암호 변경할 수 없음 </font></td>
<%
'* AND 연산을 이용한 Flag 검사
If User.UserFlags AND ADS_UF_PASSWD_CANT_CHANGE = ADS_UF_PASSWD_CANT_CHANGE Then
TempStr = "On"
Else
TempStr = "Off"
End If
%>
<td nowrap bgcolor="White"><font size="2"> <%= TempStr %> </font></td>
</tr>
<tr bgcolor="#DBDCF6">
<td nowrap align="right"><font size="2"> 암호 사용 기간 제한 없음 </font></td>
<%
'* AND 연산을 이용한 Flag 검사
If User.UserFlags AND ADS_UF_DONT_EXPIRE_PASSWD = ADS_UF_DONT_EXPIRE_PASSWD Then
TempStr = "On"
Else
TempStr = "Off"
End If
%>
<td nowrap bgcolor="White"><font size="2"> <%= TempStr %> </font></td>
</tr>
<tr bgcolor="#DBDCF6">
<%
If User.AccountDisabled Then
TempStr = "On"
Else
TempStr = "Off"
End If
%>
<td nowrap align="right"><font size="2"> 계정 사용 안함 </font></td>
<td nowrap bgcolor="White"><font size="2"> <%= TempStr %> </font></td>
</tr>
<tr bgcolor="#DBDCF6">
<%
If User.IsAccountlocked Then
TempStr = "On"
Else
TempStr = "Off"
End If
%>
<td nowrap align="right"><font size="2"> 계정 잠겨 있음 </font></td>
<td nowrap bgcolor="White"><font size="2"> <%= TempStr %> </font></td>
</tr>
</table><br><br>
<% Response.Flush %>
<% Set User = Nothing %>
</font>
</body>
</html>
|
아래 좌측의 그림은 위의 ASP 프로그램을 제 컴퓨터에서 실행시킨 결과이고, 그 우측의 그림은 실제로 'MMC' 를 통해 '컴퓨터 관리 Snap-In' 에서 살펴본 해당 계정의 등록 정보입니다. - Windows 2000 제품군 기준 : NT 4.0 의 경우에는 '도메인 사용자 관리자'를 살펴보시기 바랍니다. - 두 그림 모두 제가 테스트를 위해 지정한 계정인 'ADSI_User' 라는 계정의 각종 정보를 보여주고 있습니다. 참고로, 'ADSI_User' 라는 계정은 테스트를 위해 임시로 만든 계정으로서 Users 그룹에 속한 일반적인 계정입니다.
 |
 |
◈ ADSI 예제 프로그램 - 03. 코드 설명
이 프로그램에서는 먼저 컴퓨터 이름과 테스트할 계정을 의미하는 두 개의 상수, MachineName 과 UserID 를 설정하고, ADS_UF_PASSWD_CANT_CHANGE 와 ADS_UF_DONT_EXPIRE_PASSWD 라는 조금은 특이한 상수를 정의하고 있습니다.
ADS_UF_PASSWD_CANT_CHANGE 상수와 ADS_UF_DONT_EXPIRE_PASSWD 상수는 각각 '암호 변경할 수 없음' 속성과 '암호 사용 기간 제한 없음' 속성을 의미하는 Flag 값으로서 다른 여러가지 사용자 속성들에 관한 상수들과 함께 ADS_USER_FLAG 라는 열거형에 정의되어 있습니다. 이 두개의 상수는 프로그램의 뒷부분에서 해당 속성의 설정 여부를 알아내기 위해 사용될 것입니다. 그리고, '&h' 는 VBScript 에서 16 진수를 의미하는 토큰입니다.
'****************************************************************** '* '* 컴퓨터 이름 상수, 테스트 사용자 계정 상수 '* '* 반드시 MachineName 상수를 자신의 컴퓨터 이름으로 바꿔주어야 '* 프로그램이 정상적으로 작동한다. '* '* 반드시 UserID 상수를 자신의 컴퓨터에 존재하는 테스트 사용자 계정으로 '* 바꿔주어야 프로그램이 정상적으로 작동한다. '* '****************************************************************** Const MachineName = "송원석" Const UserID = "ADSI_User" Const ADS_UF_PASSWD_CANT_CHANGE = &h0040 Const ADS_UF_DONT_EXPIRE_PASSWD = &h10000 |
변수를 선언한 후 GetObject() 함수를 사용하여 UserID 상수에 지정한 계정의 정보를 가져옵니다. 이 예제에서 ADsPath 는 결과적으로 'WinNT://송원석/ADSI_User,User' 가 됩니다. ADsPath 에서 ',' 를 기준으로 하여 앞 부분인 'WinNT://송원석/ADSI_User' 는 '송원석' 컴퓨터의 'ADSI_User' 라는 계정을 지정하고, 뒷 부분인 'User' 는 ',' 앞 부분의 Class 유형을 지정합니다.
'******************************************************************
'*
'* ADSI 를 이용해 지정 컴퓨터의 지정 사용자 정보를 가져온다.
'*
'******************************************************************
Set User = GetObject("WinNT://" & MachineName & "/" & UserID & ",User")
|
이제 'ADSI_User' 계정의 객체를 얻었으므로 세부 속성을 보여주기만 하면 됩니다. Name, FullName, Description 속성은 각각 '계정', '긴 이름', '설명'을 나타내는 속성으로서, 이미 지난번 강좌에서 다루어진 적이 있는 속성들입니다. 그리고, AccountDisabled, IsAccountlocked 속성은 각각 '계정 사용 안함', '계정 잠겨 있음' 을 나타내는 속성으로서 해당 속성이 설정되어 있으면 True 를, 설정되어있지 않으면 False 를 반환하므로 사용하시기에 큰 어려움이 없으실 것입니다.
그러나, '암호 변경할 수 없음' 과 '암호 사용 기간 제한 없음' 을 나타내는 속성은 별도로 존재하지 않고, 다른 몇 가지 속성들과 함께 UserFlags 속성에 각각의 Flag 로 설정되므로 직접 사용할 수 없습니다. 따라서 AND 연산을 이용해서 해당 Flag 의 설정 여부를 확인해야하는데, Script 언어에만 익숙하신 분들께서는 조금 어렵게 느껴지실 수도 있으실 것입니다. (AND 연산이나 OR 연산에 대한 설명은 기타 프로그래밍 서적을 참고하시기 바랍니다.)
<tr bgcolor="#DBDCF6">
<td nowrap align="right"><font size="2"> 암호 변경할 수 없음 </font></td>
<%
'* AND 연산을 이용한 Flag 검사
If User.UserFlags AND ADS_UF_PASSWD_CANT_CHANGE = ADS_UF_PASSWD_CANT_CHANGE Then
TempStr = "On"
Else
TempStr = "Off"
End If
%>
<td nowrap bgcolor="White"><font size="2"> <%= TempStr %> </font></td>
</tr>
<tr bgcolor="#DBDCF6">
<td nowrap align="right"><font size="2"> 암호 사용 기간 제한 없음 </font></td>
<%
'* AND 연산을 이용한 Flag 검사
If User.UserFlags AND ADS_UF_DONT_EXPIRE_PASSWD = ADS_UF_DONT_EXPIRE_PASSWD Then
TempStr = "On"
Else
TempStr = "Off"
End If
%>
<td nowrap bgcolor="White"><font size="2"> <%= TempStr %> </font></td>
</tr> |
위의 코드에서 처럼 UserFlags 속성과 어떤 상수값을 AND 연산해서 원래의 어떤 상수값이 나오면 UserFlags 속성의 해당 Flag 가 설정되어있다는 뜻입니다. 따라서, AND 연산을 사용하여 해당 속성의 설정 결과를 알수 있고, 위에서 처럼 그 내용을 정리하여 결과를 보여줍니다.
◈ ADSI 예제 프로그램 - 04.
다음은 네번째 ADSI 예제 프로그램(소스 다운로드)입니다. 이 프로그램에서는 프로그램을 사용하는 사람의 권한을 인증하기 위하여 GetObject() 함수와 함께 OpenDSObject() 함수를 사용합니다.
OpenDSObject() 함수는 Administrator 와 같이 특수한 권한을 가진 사용자만 접근할 수 있는 속성에 접근하기 위한 함수입니다. 예를 들어, 우리는 지난번 강좌의 예제에서 사용자 정보, 그룹 정보와 더불어 서비스의 기본적인 정보들을 살펴볼 수 있는 목록들을 출력했었습니다. 하지만, 서비스 목록의 경우 이 목록에서 각각의 서비스들이 현재 실행되고 있는지, 혹은 멈춰져 있는지 같은 서비스 상태를 알아낼 수는 없었습니다. 서비스의 현재 서비스 상태 정보를 가지고 있는 속성은 Status 지만, 이 속성을 그냥 GetObject() 함수를 사용해서 접근하면 '일반 엑세스 오류'가 발생합니다.
어떻게 생각하면 이러한 결과는 너무도 당연한 것이고, 반드시 그렇게 되어야만 합니다. 아무나 ADSI 를 사용해서 여러분들의 서버를 조작할 수 있다면, Windows 2000 서버를 사용할 관리자는 한 사람도 없을 것입니다. 이른바 '보안'에 관련된 문제인 것입니다.
이 프로그램을 테스트하실 때 주의하실 점은 아무리, OpenDSObject() 함수를 사용해서 적절한 권한을 가진 사용자 계정으로 프로그램을 실행시킨다고 해도, 인터넷을 통해서 IIS 에 접근한 사용자는 우선 'IUSR_MachineName' 계정으로 다루어지므로, 반드시 이 프로그램 파일이나 이 프로그램이 위치한 폴더를 Administrator 그룹의 사용자만 접근 가능하도록 보안 설정을 하셔야합니다. 그러지 않으면 오류번호 0x80005000 나 0x8007052E, 혹은 0x80070520 와 같은 'ASP 내부 오류'가 발생합니다. 파일 시스템이 FAT 인 서버에서도 테스트 해봤습니다만, 역시 오류가 발생했습니다.
<%
'******************************************************************
'*
'* # TITLE : ADSI Test Program - 04.
'* # PROGRAM NAME : ADSI04.asp
'* # PROGRAM CONT. : Computer Browser 서비스의 현재 서비스 상태를
'* 알아낸다.
'* # SUB ROUTINE :
'* # CLIENT SCRIPT :
'* # INCLUDE FILES :
'* # MODIFICATIONS :
'* 1. 2000/08/12 송원석 프로그램 처음 작성
'*
'******************************************************************
Option Explicit
Response.Buffer = True
'******************************************************************
'*
'* 컴퓨터 이름 상수
'*
'* 반드시 MachineName 상수를 자신의 컴퓨터 이름으로 바꿔주어야
'* 프로그램이 정상적으로 작동한다.
'*
'* 반드시 AdminPasswd 상수를 자신의 Administrator 계정의 암호로
'* 바꿔주어야 프로그램이 정상적으로 작동한다.
'*
'******************************************************************
Const MachineName = "송원석"
Const AdminID = "Administrator"
Const AdminPasswd = "xxxxxxxxxx"
Const ADS_SECURE_AUTHENTICATION = &h1
Const ADS_SERVICE_STOPPED = &h00000001
Const ADS_SERVICE_START_PENDING = &h00000002
Const ADS_SERVICE_STOP_PENDING = &h00000003
Const ADS_SERVICE_RUNNING = &h00000004
Const ADS_SERVICE_CONTINUE_PENDING = &h00000005
Const ADS_SERVICE_PAUSE_PENDING = &h00000006
Const ADS_SERVICE_PAUSED = &h00000007
'******************************************************************
'*
'* 변수 선언
'*
'******************************************************************
Dim MyProvider, Domain
Dim Service
Dim Temp
'******************************************************************
'*
'* ADSI 를 이용해 지정 컴퓨터의 서비스 정보를 가져온다.
'*
'******************************************************************
Set MyProvider = GetObject("WinNT:")
Set Domain = MyProvider.OpenDSObject("WinNT://" & MachineName, _
AdminID, _
AdminPasswd, _
ADS_SECURE_AUTHENTICATION)
'* 서비스에 관한 정보만 가져오도록
'* Filter 를 설정한다.
Domain.Filter = Array("Service")
%>
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//EN">
<html>
<head>
<title>ADSI 테스트 04</title>
</head>
<body>
<font size="2">
◈ Computer Browser 서비스 상태 정보<br>
<table border="0" cellpadding="2" cellspacing="1" bgcolor="#BBBCE6">
<tr bgcolor="#DBDCF6">
<td nowrap align="center"><font size="2"> 서비스 </font></td>
<td nowrap align="center"><font size="2"> 서비스 이름 </font></td>
<td nowrap align="center"><font size="2"> 서비스 상태 </font></td>
</tr>
<%
For Each Service In Domain
If Service.Name = "Browser" Then
%>
<tr bgcolor="White">
<%
If ADS_SERVICE_STOPPED = Service.Status Then
Temp = "Stopped"
ElseIf ADS_SERVICE_RUNNING = Service.Status Then
Temp = "Running"
ElseIf ADS_SERVICE_PAUSED = Service.Status Then
Temp = "Paused"
ElseIf ADS_SERVICE_STOP_PENDING = Service.Status Then
Temp = "Stop Pending"
ElseIf ADS_SERVICE_START_PENDING = Service.Status Then
Temp = "Start Pending"
ElseIf ADS_SERVICE_CONTINUE_PENDING = Service.Status Then
Temp = "Countinue Pending"
ElseIf ADS_SERVICE_PAUSE_PENDING = Service.Status Then
Temp = "Pause Pending"
Else
Temp = ""
End If
%>
<td nowrap><font size="2"> <%= Service.Name %> </font></td>
<td nowrap><font size="2"> <%= Service.DisplayName %> </font></td>
<td nowrap><font size="2"> <%= Temp %> </font></td>
</tr>
<%
End If
Next
%>
</table><br><br>
<% Response.Flush %>
<%
Set Domain = Nothing
Set MyProvider = Nothing
%>
</font>
</body>
</html>
|
 |
이처럼 OpenDSObject() 함수를 사용하면 GetObject() 함수만으로는 접근할 수 없는 속성도 자유롭게 접근, 또는 수정하실 수 있습니다.
◈ ADSI 예제 프로그램 - 04. 코드 설명
이 프로그램에서도 역시 첫부분에서 몇 개의 상수를 선언하고 있습니다. 컴퓨터 이름과 사용할 계정, 그리고 사용할 계정의 암호를 의미하는 세개의 상수 MachineName, AdminID, AdminPasswd 를 선언하고, OpenDSObject() 함수에서 사용될 ADS_SECURE_AUTHENTICATION 상수와 현재 서비스의 상태를 뜻하는 ADS_SERVICE... 로 시작하는 몇 개의 상수를 추가로 선언하고 있습니다.
그리고, 상수를 선언하는 부분을 제외한 나머지 부분들 중에서 OpenDSObject() 함수를 사용하는 부분을 뺀 나머지 부분들은 여러분들께서 모두 쉽게 이해하실 수 있는 내용들이므로 일단 여기에서는 OpenDSObject() 함수를 중점적으로 설명드리겠습니다.
'******************************************************************
'*
'* ADSI 를 이용해 지정 컴퓨터의 서비스 정보를 가져온다.
'*
'******************************************************************
Set MyProvider = GetObject("WinNT:")
Set Domain = MyProvider.OpenDSObject("WinNT://" & MachineName, _
AdminID, _
AdminPasswd, _
ADS_SECURE_AUTHENTICATION)
'* 서비스에 관한 정보만 가져오도록
'* Filter 를 설정한다.
Domain.Filter = Array("Service")
%>
|
사실 OpenDSObject() 함수를 중점적으로 설명드린다고 말씀은 드렸지만, 위에 나타나 있는 코드가 이 함수의 사용법의 전부라서 더 설명할 것도 없습니다. 먼저 GetObject() 함수를 이용해 정보를 얻고자 하는 ADSI 제공자의 최상위 객체를 가져옵니다. 그리고 이렇게 얻은 객체의 메쏘드인 OpenDSObject() 함수를 그대로 사용하면 되는 것입니다.
OpenDSObject() 함수에는 모두 네개의 인자가 존재하는데 첫번째 인자는 ADsPath 이고, 두번째 인자는 적당한 권한을 가진 사용자의 계정입니다. 그리고 세번째 인자는 그 계정에 대한 암호입니다. 마지막으로 네번째 인자에는 보안 설정을 결정하는 ADS_SECURE_AUTHENTICATION 상수가 들어갑니다. 네번째 인자에 들어갈 수 있는 상수에는 ADS_SECURE_AUTHENTICATION 외에도 몇 가지가 더 있습니다만, 일단 넘어가기로 하겠습니다. ADS_SECURE_AUTHENTICATION 상수는 서버에서 보안 인증을 해야만한다는 의미를 가지고 있습니다.
◈ 마치며...
지난번 강좌에서부터 이번 강좌까지 두 번에 걸쳐 모두 네가지의 ADSI 관련 예제를 보여드렸습니다. 비록 상세한 설명은 없었지만, 여러분들께서는 이미 ADSI 의 대략적인 아웃라인을 충분히 파악하셨을 것이라고 생각합니다.
하지만 분명히 답답하신 점들이 있으실 것입니다. 제가 아무때나 불쑥 선언하곤 하는 상수들은 도대체 어디에서 알아내는 것인지, 지금까지 예제들에서 기존에 존재하는 속성들의 값을 가져오기는 했는데, 값 설정은 어떻게 하는 것인지, 그리고 어떤 자원들을 ADSI 로 조작할 수 있는지, 무슨무슨 속성들이 있는지 등등...
이제 다음 강좌에서 부터는 바로 그런 궁금증들을 하나하나 해결해가도록 하겠습니다.
감사합니다.